编程知识 购物 网址 新闻 笑话 | 软件 日历 阅读 图书馆 China
TxT小说阅读器
↓语音阅读,小说下载,古典文学↓
图片批量下载器
↓批量下载图片,美女图库↓
图片自动播放器
↓图片自动播放器↓
一键清除垃圾
↓轻轻一点,清除系统垃圾↓
vbs/VBScript DOS/BAT hta htc python perl 游戏相关 VBA 远程脚本 ColdFusion ruby专题 autoit seraphzone PowerShell linux shell Lua Golang Erlang 其它教程 CSS/HTML/Xhtml html5 CSS XML/XSLT Dreamweaver教程 经验交流
站长资讯 .NET新手 ASP.NET C# WinForm Silverlight WCF CLR WPF XNA VisualStudio ASP.NET-MVC .NET控件开发 EntityFramework WinRT-Metro Java C++ PHP Delphi Python Ruby C语言 Erlang Go Swift Scala R语言 Verilog 其它语言 架构设计 面向对象 设计模式 领域驱动 Html-Css JavaScript jQuery HTML5 SharePoint GIS技术 SAP OracleERP DynamicsCRM K2 BPM 信息安全 企业信息 Android开发 iOS开发 WindowsPhone WindowsMobile 其他手机 敏捷开发 项目管理 软件工程 SQLServer Oracle MySQL NoSQL 其它数据库 Windows7 WindowsServer Linux
   -> vbs/VBScript -> vbs能调用的系统对象小结 -> 正文阅读

[vbs/VBScript]vbs能调用的系统对象小结

这篇文章主要介绍了vbs能调用的系统对象小结,需要的朋友可以参考下
vbs能调用系统对象:
文件系统对象相关: ("scripting.filesystemobject")
字典相关: ("scripting.dictionary")
脚本外壳相关: ("wscript.shell")
windows外壳相关: ("shell.application")
正则表达式相关: ("vbscript.regexp")
asp相关: ("mswc.adrotator") ("mswc.nextlink") ("mswc.myinfo")
公用对话框相关: ("mscomdlg.commondialog")?
编码与密码相关: ("scriptpw.password")? (?"scripting.encoder"?)
邮件发送的组件相关: ("jmail.message") ("cdonts.newmail") ("cdo.configuration") ("eudora.euapplication.1") ("novellgroupwaresession")
水晶报表相关: ?("crystalruntime.application")?
ie浏览器相关:? ("internetexplorer.application")?
windows媒体播放相关:? ("wmplayer.ocx") ("wmplayer.ocx.7"?)
助手角色相关: ("agent.control")
ado相关: ("adodb.connection") ("adodb.command") ("adodb.recordset") ("adodb.record") ("adodb.stream") ("dao.dbengine.35") ("adox.catalog") ("adox.table")
sql相关: ("sqldmo.sqlserver") ("sqldmo.login") ("sqldmo.backup") ("sqldmo.user") ("sqldmo.backupdevice") ("sqldmo.database") ("sqldmo.restore") ("sqldmo.application") office相关: ("word.application") ("excel.application") ("powerpoint.application") ("excel.sheet") ("frontpage.application") ("access.application") ("msgraph.application") ("outlook.application")
图像图形相关: ("aspimage.jpeg") ("persits.jpeg") ("activeimage.images.1")? ("jsdraw.ops") ("jsiptc.jpgedit") ("gflax.gflax") ("photoshop.application")
语音朗读相关: ("speech.voicetext") ("speech.voicetext.1") ("sapi.spvoice") ("sapi.spfilestream") ("texttospeech.texttospeech") ("texttospeech.texttospeech.1") ("activevoice.activevoice") ("activevoice.activevoice.1")
操作系统相关: ("jsdlgbox.browser") ("jsbin.binaryops") ("jsform.window") ("jslistvw.list") ("jssys3.ops") ("jssys3.iniedit")? ("tli.tliapplication") ("autoitx3.control") ("windowsinstaller.installer") ("virtualserver.application") ("useraccounts.commondialog") ("mosearch.gatherlog.1") ("mscomdlg.commondialog")
wmi相关: ("wbemscripting.swbemdatetime") ("wbemscripting.swbemlocator") ("wbemscripting.swbemnamedvalueset") ("wbemscripting.swbemsink",?"sink_")? ("wbemscripting.swbemrefresher") ("wbemscripting.swbemlasterror") ("wbemscripting.swbemobjectpath")
web,net相关: ("winhttp.winhttprequest") ("winhttp.winhttprequest.5.1") ("msxml2.serverxmlhttp") ("microsoft.xmlhttp") ("microsoft.xmldom") ("msxml2.xmlhttp.4.0") ("wscript.network") ("asphttp.conn") ("inetctls.inet") ("post.clspost") ("webget.web") ("netcommocx.netcomm",?"com_")? ("mswinsock.winsock") ("rcbdyctl.setting") ================================== 其他罕见的类型库,如果你用得着,也可以列入常用库:
消息队列: ("msmq.msmqmessage") ("msmq.msmqqueueinfo") ("msmq.msmqquery")
索引服务: ("ixsso.query") ("ixsso.util")
信使服务: ("messenger.msgrobject") ("messenger.messengerapp") ("msnmessenger.messengerapp")
打印和传真: ("winprint.winprintx") ("winfax.sdksend")? (faxserver.faxserver) ("fmfaxapi.application") ("oleprn.dsprintqueue.1")
数据库会话: ("accpac.xapisession")
报表与pdf发布: ("impromptu.application.30")
条形码与标签: ("bartender.application")
邮件群发: ("notes.notessession") ("notes.notesuiworkspace") ("notes.notesuiworkspace")
网络会议: ("netmeeting.app.1")
ms编程: ("msproject.application") ("sourcesafe.0")
路由与映射: ("mappoint.application")
矢量绘图: ("visio.application")
建模: ("rose.application")
再谈CreateObject函数,VBS到底能调用哪些对象?
VBS的CreateObject函数到底能够创建哪些对象,几乎是每个VBS新手都困惑的问题,他们总是热衷于寻找“VBS对象大全”。
对象的注册信息 HKEY_CLASSES_ROOT\CLSID\{GUID} 下可能会有这样的一些子键:Control 说明该组件是一个 ActiveX 控件、Programmable 说明该组件支持自动化、Insertable 说明该组件可以被嵌入到一个 OLE 文档容器中。能找到 Programmable,说明支持自动化,也就是支持 IDispatch 接口,所以它可以被脚本语言使用。不过这种方式比较老了,现在已经被一个的组件类属代替,即 Implemented Categories 子键下面的 GUID 形式的子键。比如 HKEY_CLASSES_ROOT\CLSID\{72C24DD5-D70A-438B-8A42-98424B88AFB8}\Implemented Categories\{40FC6ED5-2438-11CF-A3DB-080036F12502},看一下 HKEY_CLASSES_ROOT\Component Categories\{40FC6ED5-2438-11CF-A3DB-080036F12502} 下的 409 字符串值为 Automation Objects,也就是“自动化对象”。
也就是说,如果注册表中一个对象的ProgID对应的CLSID下包含有子键Programmable或者Implemented Categories\{40FC6ED5-2438-11CF-A3DB-080036F12502},那么这个对象就能用CreateObject函数创建。
假设上面的说法正确,那么我们可以用下面的脚本获取“VBS对象大全”:

Option Explicit

Const HKEY_CLASSES_ROOT = &H80000000
Dim arrProgID, strProgID, strCLSID
Dim objReg, objFso, objFile, objShell

Set objReg = GetObject("winmgmts:\\.\root\default:StdRegProv")
Set objFso = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("WScript.Shell")

Set objFile = objFso.OpenTextFile("ProgID.txt", 2, True)

'By Demon
'http://demon.tw

objReg.EnumKey HKEY_CLASSES_ROOT, "", arrProgID
For Each strProgID In arrProgID
 If GetCLSID(strProgID, strCLSID) Then
  If IsProgrammable(strCLSID) Or IsAutomationObject(strCLSID) Then
   objFile.WriteLine strProgID
  End If
 End If
Next
objShell.Run "ProgID.txt"

Function RegKeyExists(hKey, strSubKey)
 Dim a, n
 n = objReg.EnumKey(hKey, strSubKey, a)
 If n = 0 Then
  RegKeyExists = True
 Else
  RegKeyExists = False
 End If
End Function

Function IsAutomationObject(strCLSID)
 Dim strSubKey
 IsAutomationObject = False
 strSubKey = "CLSID\" & strCLSID & "\Implemented Categories"
 If RegKeyExists(HKEY_CLASSES_ROOT, strSubKey) Then
  strSubKey = strSubKey & "{40FC6ED5-2438-11CF-A3DB-080036F12502}"
  If RegKeyExists(HKEY_CLASSES_ROOT, strSubKey) Then
   IsAutomationObject = True
  End If
 End If
End Function

Function IsProgrammable(strCLSID)
 IsProgrammable = RegKeyExists(HKEY_CLASSES_ROOT, _
  "CLSID\" & strCLSID & "\Programmable")
End Function

Function GetCLSID(strProgID, strCLSID)
 Dim s
 GetCLSID = False
 If RegKeyExists(HKEY_CLASSES_ROOT, strProgID & "\CLSID") Then
  objReg.GetStringValue HKEY_CLASSES_ROOT, strProgID & "\CLSID", "", s
  If Not IsNull(s) Then
   strCLSID = s
   GetCLSID = True
  End If
 End If
End Function

上面的脚本显示在我的系统中存在1000多个对象可以调用。哇!VBS居然可以调用那么多对象!别高兴得太早,我前面说了“假设上面的说法正确”。实际上,UMU的说法并不完全正确,Programmable或者Implemented Categories为{40FC6ED5-2438-11CF-A3DB-080036F12502}的对象也不一定能够用CreateObject创建,比如我系统中有一个ComCtl3.Band就属于这种情况;另外,某些对象并没有Programmable或者Implemented Categories,但是照样可以用CreateObject创建,比如说WindowsInstaller.Installer。
所以不能单纯依靠注册表的是非存在Programmable或者Implemented Categories来判断,那么如果来判断呢?一种方法是根据《VBS技术内幕:CreateObject函数》里面说的,写一个C++程序来模拟CreateObject函数,判断对象是否支持IDispatch接口。不过这样太麻烦了,比较简单的方法是让CreateObject函数自己来判断:

Option Explicit

Const HKEY_CLASSES_ROOT = &H80000000
Dim arrProgID, strProgID, strCLSID
Dim objReg, objFso, objFile, objShell, O

Set objReg = GetObject("winmgmts:\\.\root\default:StdRegProv")
Set objFso = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("WScript.Shell")

Set objFile = objFso.OpenTextFile("ProgID.txt", 2, True)

'By Demon
'http://demon.tw

objReg.EnumKey HKEY_CLASSES_ROOT, "", arrProgID
For Each strProgID In arrProgID
 If GetCLSID(strProgID, strCLSID) Then
  If IsCreatable(strProgID) Then
   objFile.WriteLine strProgID
  End If
 End If
Next
objShell.Run "ProgID.txt"

Function IsCreatable(strProgID)
 On Error Resume Next
 Dim O
 Set O = CreateObject(strProgID)
 If Err.Number = 0 Then
  IsCreatable = True
 Else
  IsCreatable = False
 End If
 Set O = Nothing
 Err.Clear
End Function

Function RegKeyExists(hKey, strSubKey)
 Dim a, n
 n = objReg.EnumKey(hKey, strSubKey, a)
 If n = 0 Then
  RegKeyExists = True
 Else
  RegKeyExists = False
 End If
End Function

Function GetCLSID(strProgID, strCLSID)
 Dim s
 GetCLSID = False
 If RegKeyExists(HKEY_CLASSES_ROOT, strProgID & "\CLSID") Then
  objReg.GetStringValue HKEY_CLASSES_ROOT, strProgID & "\CLSID", "", s
  If Not IsNull(s) Then
   strCLSID = s
   GetCLSID = True
  End If
 End If
End Function

说了这么多,其实我真正想说的是,就算你用上面的脚本得到了“VBS对象大全”又有什么意义呢?我敢肯定的告诉你,这些对象里面有95%以上你从来都见过,也不知道它们是做什么的,更不用说去调用。
我常用的VBS对象只有下面几个:
ADODB.Stream
InternetExplorer.Application
Msxml2.XMLHTTP
Scripting.Dictionary
Scripting.FileSystemObject
Shell.Application
WScript.Shell
把这些对象都弄懂了,VBS基本上就入门了。
以上部分内容来自:http://demon.tw/programming/createobject-again.html
  vbs/VBScript 最新文章
vbscript基础篇 - vbs变量定义与使用方法
vbscript基础篇 - vbs数组Array的定义与使用
VBScript 根据IE窗口的标题输出ESC
vbscript网页模拟登录效果代码
vbs能调用的系统对象小结
VBS技术内幕:CreateObject函数详解
用vbs实现删除名称中有撇号的文件夹
iPod文本分割器(VBS版)
VBScript教程 第十三课 VBScript与窗体
VBS教程:VBscript属性-Number 属性
上一篇文章      下一篇文章      查看所有文章
加:2018-05-09 23:30:53  更:2018-05-09 23:30:57 
 
360图书馆 软件开发资料 购物精选 新闻资讯 Chinese Culture 三丰软件 开发 中国文化 阅读网 日历 万年历 2019年12日历
2019-12-9 17:40:38
多播视频美女直播
↓电视,电影,美女直播,迅雷资源↓
TxT小说阅读器
↓语音阅读,小说下载,古典文学↓
一键清除垃圾
↓轻轻一点,清除系统垃圾↓
图片批量下载器
↓批量下载图片,美女图库↓
  网站联系: qq:121756557 email:121756557@qq.com  编程知识